hister/flake.nix at d84749886b08c071021f8586257b019daa25417c · FlameFlag/hister · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
{
  description = "Hister - Web history on steroids";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
    flake-parts.url = "github:hercules-ci/flake-parts";
    flake-parts.inputs.nixpkgs-lib.follows = "nixpkgs";
  };

  outputs =
    inputs:
    inputs.flake-parts.lib.mkFlake { inherit inputs; } {
      systems = [
        "x86_64-linux"
        "x86_64-darwin"
        "aarch64-linux"
        "aarch64-darwin"
      ];

      perSystem =
        {
          config,
          self',
          inputs',
          pkgs,
          system,
          ...
        }:
        let
          histerPackage = pkgs.callPackage ./nix/package.nix { histerRev = inputs.self.rev or "unknown"; };
        in
        {
          packages.default = histerPackage;
          packages.hister = histerPackage;

          devShells.default = pkgs.mkShell {
            packages = builtins.attrValues { inherit (pkgs) go gopls gotools; };
          };
        };

      flake = {
        nixosModules.default = inputs.self.nixosModules.hister;
        nixosModules.hister =
          { lib, pkgs, ... }:
          {
            imports = [ ./nix/nixos.nix ];
            services.hister.package = (
              lib.mkDefault inputs.self.packages.${pkgs.stdenvNoCC.hostPlatform.system}.default
            );
          };

        homeModules.default = inputs.self.homeModules.hister;
        homeModules.hister =
          { lib, pkgs, ... }:
          {
            imports = [ ./nix/home.nix ];
            services.hister.package = (
              lib.mkDefault inputs.self.packages.${pkgs.stdenvNoCC.hostPlatform.system}.default
            );
          };

        darwinModules.default = inputs.self.darwinModules.hister;
        darwinModules.hister =
          { lib, pkgs, ... }:
          {
            imports = [ ./nix/darwin.nix ];
            services.hister.package = (
              lib.mkDefault inputs.self.packages.${pkgs.stdenvNoCC.hostPlatform.system}.default
            );
          };
      };
    };
}