box.app/settings.gradle.kts at main · MiChongs/box.app · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
// settings.gradle.kts
pluginManagement {
    repositories {
        google {
            content {
                includeGroupAndSubgroups("com.android")
                includeGroupAndSubgroups("com.google")
                includeGroupAndSubgroups("androidx")
            }
        }
        mavenCentral()
        gradlePluginPortal()
    }
}

dependencyResolutionManagement {
    repositoriesMode.set(RepositoriesMode.FAIL_ON_PROJECT_REPOS)
    repositories {
        val jitpackToken = providers.gradleProperty("authToken").orNull?.takeIf { it.isNotBlank() }

        google()
        mavenCentral()
        maven("https://jitpack.io") {
            if (jitpackToken != null) {
                credentials {
                    username = jitpackToken
                    password = ""
                }
            }
            content {
                includeGroup("com.github.topjohnwu.libsu")
                includeGroup("com.github.getActivity")
            }
        }
        maven("https://maven.aliyun.com/repository/public")
        maven("https://maven.pkg.github.com/ReChronoRain/HyperCeiler") {
            val ghToken = providers.gradleProperty("hyperceilerToken").orNull?.takeIf { it.isNotBlank() }
            if (ghToken != null) {
                credentials {
                    username = "MiChongs"
                    password = ghToken
                }
            }
            content {
                includeGroup("fan.miuix")
            }
        }
    }
}

rootProject.name = "BoxReApp"
include(":app")
include(":libs:hyperx-compose")
project(":libs:hyperx-compose").projectDir = file("libs/hyperx-compose")