hister/nix/home.nix at a9c29cb3d17cf82ea8478c08b00b2d16ad45b9ee · SKalt/hister · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
{
  config,
  lib,
  histerEnv,
  ...
}:
{
  imports = [
    ./options.nix
  ];

  config = lib.mkIf config.services.hister.enable {
    home.packages = [ config.services.hister.package ];

    systemd.user.services.hister = {
      Unit = {
        Description = "Hister web history service";
        After = [ "network.target" ];
      };

      Service = {
        ExecStart = "${lib.getExe config.services.hister.package} listen";
        Restart = "on-failure";
        WorkingDirectory = lib.mkIf (config.services.hister.dataDir != null) config.services.hister.dataDir;

        Environment = lib.mapAttrsToList (name: value: "${name}=${value}") (
          histerEnv config.services.hister
        );
      };

      Install = {
        WantedBy = [ "default.target" ];
      };
    };

    launchd.agents.hister = {
      enable = true;
      config = {
        ProgramArguments = [
          (lib.getExe config.services.hister.package)
          "listen"
        ];
        KeepAlive = true;
        WorkingDirectory = lib.mkIf (config.services.hister.dataDir != null) config.services.hister.dataDir;

        EnvironmentVariables = histerEnv config.services.hister;
      };
    };
  };
}