PKGBUILD

# Copyright (C) 2016-2018  Andrew Gunnerson <andrewgunnerson@gmail.com>
#
# This program is free software: you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation, either version 3 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program.  If not, see <http://www.gnu.org/licenses/>.

_prebuilts='https://dbp.noobdev.io/repo/prebuilts'
_ver_libpng=8.1.0_r2-2

pkgname=freetype2
pkgver=8.1.0_r2
pkgrel=2
pkgdesc="TrueType font rendering library"
arch=(armv7 aarch64 x86 x86_64)
url="https://android.googlesource.com/platform/external/freetype"
license=(GPL)
source=("git+https://android.googlesource.com/platform/external/freetype#tag=android-${pkgver}"
        0001-Add-Android.mk.patch)
_source_template=("${_prebuilts}/libpng-${_ver_libpng}-@ARCH@.pkg.tar.xz"
                  "${_prebuilts}/libpng-${_ver_libpng}-@ARCH@.pkg.tar.xz.sig")
source_armv7=("${_source_template[@]/@ARCH@/armv7}")
source_aarch64=("${_source_template[@]/@ARCH@/aarch64}")
source_x86=("${_source_template[@]/@ARCH@/x86}")
source_x86_64=("${_source_template[@]/@ARCH@/x86_64}")
noextract=("libpng-${_ver_libpng}-${CARCH}.pkg.tar.xz")
validpgpkeys=('2233C479609BDCEC43BE9232F6A3B19090EFF32C')

prepare() {
    cd freetype
    patch -p1 -i ../0001-Add-Android.mk.patch

    mkdir -p common
    cd common

    mkdir -p libpng
    bsdtar -xf "${srcdir}/libpng-${_ver_libpng}-${CARCH}.pkg.tar.xz" -C libpng
}

build() {
    cd freetype

    local abi
    abi=$(android_get_abi_name)

    ndk-build \
        NDK_PROJECT_PATH=. \
        NDK_TOOLCHAIN_VERSION=clang \
        APP_BUILD_SCRIPT=Android.mk \
        APP_ABI="${abi}" \
        APP_PLATFORM=android-28 \
        "${MAKEFLAGS}"
}

package() {
    cd freetype

    local abi
    abi=$(android_get_abi_name)

    install -dm755 "${pkgdir}"/lib/
    install -m644 "obj/local/${abi}/libft2.a" "${pkgdir}"/lib/
    install -dm755 "${pkgdir}"/include/
    cp -a include/. "${pkgdir}"/include/
}

sha512sums=('SKIP'
            '7de6df668a8ba974a8105263bac554c682bcea2dfc53062df013a186b818f66986639362d026be969d42a5f3248705d15cd7e937e0402883c4f26eff53781c1e')
sha512sums_armv7=('d7e3a1d01b06db858e0fa76248db06a7e7e40f5c9eb9df8a484f0102c4bf637cecbdfbb96d5aef29cc52cb1804eb134631d0e1c4dbb444c0585af8270f5bfc20'
                  'SKIP')
sha512sums_aarch64=('b53337eb0e552bc0aeeeffdabd99216ab441bac17ece16542a24c36504d6c12953e95f3c7c3a1b0a10146fa1c91f3e0c7fbe9781e967a9c20f975c1b00758642'
                    'SKIP')
sha512sums_x86=('187b79724027d65e46973e516559532b8216aeb02b886ca7932d074c1365dc0b83cab75139616a8a657a873a4dc5ae2fbe36e4d406d85b51fc43b4662760f9e3'
                'SKIP')
sha512sums_x86_64=('70bfd7733dc5f1fb5886a7d6cbe3bca57795ed1047ffaa9eb446dde5250bb8e0bcfb6804c35b48d49d0341a3b6662154ba34ea74934b0ca453ae2931032e29db'
                   'SKIP')