glint/justfile at main · vaporif/glint · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
default:
    @just --list

check: clippy test check-fmt lint

lint: lint-toml check-typos check-nix-fmt lint-actions

fmt: fmt-rust fmt-toml fmt-nix

build *args:
    cargo build --workspace {{args}}

clippy:
    cargo clippy --workspace -- -D warnings

test:
    cargo nextest run --workspace

coverage:
    cargo llvm-cov nextest --workspace --lcov --output-path lcov.info --ignore-filename-regex '(bin/|e2e/)'

coverage-html:
    cargo llvm-cov nextest --workspace --html --ignore-filename-regex '(bin/|e2e/)'

check-fmt:
    cargo fmt --all -- --check

fmt-rust:
    cargo fmt --all

lint-toml:
    taplo check

fmt-toml:
    taplo fmt

check-nix-fmt:
    alejandra --check flake.nix

fmt-nix:
    alejandra flake.nix

check-typos:
    typos

lint-actions:
    actionlint

run-eth *args:
    cargo run -p glint-node-eth -- node --chain etc/genesis.json {{args}}

run-op *args:
    cargo run -p glint-node-op -- node --chain etc/genesis.json {{args}}

run-sidecar *args:
    cargo run -p glint-sidecar -- {{args}}

e2e:
    docker build -f docker/Dockerfile.node -t eth-glint:latest .
    docker build -f docker/Dockerfile.sidecar -t glint-sidecar:latest .
    cargo nextest run -p glint-e2e --run-ignored all